home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib16.dsk / DISK PREPARER.bas < prev    next >
Encoding:
BASIC Source File  |  1990-01-01  |  4.5 KB  |  90 lines
  1. 10  REM  **********************
  2. 11  REM  *   DISK  PREPARER   *
  3. 12  REM  *   BY BARRY KALET   *
  4. 13  REM  * COPYRIGHT (C) 1983 *
  5. 14  REM  * BY MICROSPARC, INC *
  6. 15  REM  * LINCOLN, MA. 01773 *
  7. 16  REM  **********************
  8. 140 TD$ = "X": TEXT : HOME 
  9. 150  FOR I = 768 TO 790: READ J: POKE I,J: NEXT I
  10. 160  DATA  162,0,32,117,253,160,2
  11. 170  DATA  138,145,105,200,169,0
  12. 180  DATA  145,105,200,169,2,145
  13. 190  DATA  105,76,57,213
  14. 200  HOME :Q$ =  CHR$(34)
  15. 210  FLASH : SPEED= 50: VTAB 2: FOR K = 1 TO 20: PRINT "/";: NEXT K: FOR K = 1 TO 20: PRINT  CHR$(92);: NEXT K
  16. 220  SPEED= 100: NORMAL : VTAB 7: HTAB 3: PRINT "INSERT A  ";: INVERSE : PRINT "BLANK DISKETTE";: NORMAL : PRINT " INTO DRIVE 1"
  17. 230  SPEED= 100: VTAB 2: FOR K = 1 TO 20: PRINT "/";: NEXT K: FOR K = 1 TO 20: PRINT  CHR$(92);: NEXT K
  18. 240  VTAB 18: FOR K = 1 TO 20: PRINT  CHR$(92);: NEXT K: FOR K = 1 TO 20: PRINT "/";: NEXT K
  19. 250  NORMAL : VTAB 4: HTAB 15: SPEED= 255: NORMAL : PRINT "C A U T I O N"
  20. 260  VTAB 11: PRINT "ANY INFORMATION ON THIS DISKETTE WILL BE"
  21. 270  HTAB 11: PRINT "COMPLETELY OVERWRITTEN": PRINT : PRINT : PRINT "** COPYRIGHT 1983 BY MICROSPARC, INC. **"
  22. 280  FOR J = 1 TO 2000: NEXT J
  23. 290  VTAB 20: HTAB 19: PRINT "PRESS"
  24. 300  PRINT : HTAB 30: PRINT "<RETURN>";: HTAB 4: PRINT "<ESC>"
  25. 310  HTAB 28: PRINT "TO CONTINUE";: HTAB 3: PRINT "TO QUIT"
  26. 320  FOR J = 1 TO 1000: NEXT J
  27. 330  VTAB 22: HTAB 20: PRINT "< >"; CHR$(8); CHR$(8);: GET A$
  28. 340  IF A$ =  CHR$(13)  THEN  GOTO 370
  29. 350  IF A$ =  CHR$(27)  THEN  HOME : TEXT : END 
  30. 360  GOTO 330
  31. 370  REM  ---INITIALIZING---
  32. 380  HOME : FOR I = 1 TO 20: VTAB 8: PRINT "/";: PRINT  CHR$(8);: VTAB 12: PRINT  CHR$(92);: NEXT I
  33. 390  FOR I = 1 TO 20: VTAB 8: PRINT  CHR$(92);: PRINT  CHR$(8);: VTAB 12: PRINT "/";: NEXT I
  34. 400  VTAB 10: HTAB 10: PRINT "ARE YOU SURE? (Y/N) ";: GET A$: IF A$ = "N"  THEN 540
  35. 410  IF A$ = "Y"  THEN  VTAB 20: HTAB 1: CALL  -958: GOTO 430
  36. 420  IF A$ < >"N"  THEN 400
  37. 430  VTAB 10: HTAB 1: CALL  -868
  38. 440  PRINT  CHR$(4):TD$ = "X"
  39. 450  VTAB 10: PRINT "ENTER YOUR NAME ";: FOR I = 1 TO 24: PRINT  CHR$(95);: NEXT I: FOR I = 1 TO 24: PRINT  CHR$(8);: NEXT I: INPUT "";NAME$
  40. 460  VTAB 11: PRINT "ENTER THE DATE  ";: FOR I = 1 TO 24: PRINT  CHR$(95);: NEXT I: FOR I = 1 TO 24: PRINT  CHR$(8);: NEXT I
  41. 470  CALL 768:TD$ =  MID$ (TD$,1)
  42. 480  VTAB 11: HTAB 1: CALL  -868: VTAB 10: HTAB 1: CALL  -868
  43. 490 J = 1:S = 1
  44. 500  ONERR  GOTO 570
  45. 510  REM  --CATALOGER--
  46. 520  VTAB 10: HTAB 17: PRINT "CATALOG": VTAB 11: HTAB 18: PRINT "CHECK": POKE 34,15: PRINT  CHR$(4);"CATALOG"
  47. 530  TEXT : VTAB 10: HTAB 1: CALL  -868: VTAB 11: HTAB 1: CALL  -868: VTAB 10: HTAB 13: PRINT "CONTINUE? (Y/N) ";: GET A$: POKE 34,13: VTAB 13: HOME : TEXT : IF A$ = "Y"  THEN 560
  48. 540  IF A$ = "N"  THEN  HOME : TEXT : END 
  49. 550  GOTO 530
  50. 560  VTAB 10: HTAB 1: CALL  -868: GOTO 700
  51. 570 Y =  PEEK(222)
  52. 580  IF Y = 8  THEN  TEXT : POKE 216,0:J = J +1: IF J <3 GOTO 700
  53. 590  ONERR  GOTO 610
  54. 600  PRINT  CHR$(4);"OPEN H"
  55. 610 S = S +1: IF S = 4  THEN  VTAB 20: PRINT "REFER TO DOS MANUAL": END 
  56. 620 Y =  PEEK(222): IF Y = 4 GOTO 660
  57. 630  IF Y = 8  THEN  TEXT : VTAB 10: HTAB 12: PRINT "NO DISK IN DRIVE": VTAB 11: HTAB 13: PRINT "CONTINUE? (Y/N) ";: GET A$: PRINT  CHR$(4): POKE 216,0: VTAB 10: HTAB 1: CALL  -868: VTAB 11: HTAB 1: CALL  -868:J = 1: IF A$ = "Y"  THEN 500
  58. 640  IF A$ = "N"  THEN 540
  59. 650  GOTO 630
  60. 660  TEXT : VTAB 10: HTAB 10: PRINT "DISK IS WRITE PROTECTED": VTAB 11: HTAB 13: PRINT " CONTINUE? (Y/N) ";: GET A$: IF A$ = "Y"  THEN 690
  61. 670  IF A$ = "N"  THEN 540
  62. 680  GOTO 660
  63. 690  TEXT : VTAB 10: HTAB 1: CALL  -868: VTAB 11: HTAB 1: CALL  -868:J = 1: PRINT  CHR$(4): POKE 216,0: GOTO 500
  64. 700  PRINT  CHR$(4): VTAB 10: HTAB 15: PRINT "INITIALIZING"
  65. 710  VTAB 11: HTAB 17: PRINT "DISKETTE"
  66. 720  PRINT  CHR$(4): VTAB 14: CALL  -958: PRINT  CHR$(4)
  67. 730  ONERR  GOTO 570
  68. 740  PRINT  CHR$(4);"INIT HELLO,D1"
  69. 750 C$ = " ON "
  70. 760  PRINT  CHR$(4);"OPEN DOIT": PRINT  CHR$(4);"WRITE DOIT"
  71. 770  PRINT "POKE 50,128": PRINT "FP": PRINT " POKE 50,128"
  72. 780  PRINT "HOME"
  73. 790  PRINT "10 TEXT:HOME:POKE 50,255:PRINT CHR$(4);"Q$"DELETE DOIT"Q$
  74. 800  PRINT "20 PRINT CHR$(4);"Q$"DELETE TEMP"Q$
  75. 810  PRINT "HOME"
  76. 820  PRINT "30 PRINT CHR$(4);"Q$"RUN HELLO"Q$
  77. 830  PRINT "HOME"
  78. 840  PRINT "SAVE TEMP"
  79. 850  PRINT "HOME"
  80. 860  PRINT "10 PRINT "Q$"THIS HELLO PROGRAM CREATED BY"Q$
  81. 870  PRINT "20 PRINT "Q$NAME$C$TD$Q$
  82. 880  PRINT "30 END"
  83. 890  PRINT "DELETE HELLO"
  84. 900  PRINT "HOME"
  85. 910  PRINT "SAVE HELLO"
  86. 920  PRINT "HOME"
  87. 930  PRINT "RUN TEMP"
  88. 940  PRINT  CHR$(4);"CLOSE DOIT"
  89. 950  POKE 34,0: POKE 35,1: POKE 33,0: HOME 
  90. 999  PRINT  CHR$(4);"EXEC DOIT": HOME : END